<script> ::= <unlocking-script> <locking-script>
<unlocking-script> ::= <constants> | <empty>
<locking-script> ::= <script-block> ["OP_RETURN" <non-script-data>]
<script-block> ::=
<function> [<script-block>] |
<push-data> [<script-block>] |
<branch> [<script-block>] |
"OP_RETURN" [<script-block>] |
<empty>
<branch> ::=
<op-if> <script-block> ["OP_ELSE" <script-block>]
"OP_ENDIF"
<op-if> ::= "OP_IF" | "OP_NOTIF"
<constants> ::= <constant> [<constants>]
<constant> ::=
"OP_PUSHDATA1" <count-1> "bytes" |
"OP_PUSHDATA2" <count-2> "bytes" |
"OP_PUSHDATA4" <count-4> "bytes" |
<op-push-xx> "bytes" | <op-false> |
<op-true> | "OP_2" | "OP_3" | "OP_4" |
"OP_5" | "OP_6" | "OP_7" | "OP_8" | "OP_9" |
"OP_10" | "OP_11" | "OP_12" | "OP_13" |
"OP_14" | "OP_15" | "OP_16"
<count-1> ::= a one byte unsigned integer (0-255)
<count-2> ::= a two byte unsigned integer (0-65535, little-endian encoded)
<count-4> ::= a four byte unsigned integer (0-4294967295, little-endian encoded)
<op-push-xx> ::= hex codes 0x01 to 0x4b
<op-false> ::= "OP_0" | "OP_FALSE"
<op-true> ::= "OP_1" | "OP_TRUE"
<function> ::=
"OP_NOP" | "OP_VERIFY" |
"OP_TOALTSTACK" | "OP_FROMALTSTACK" | "OF_IFDUP" |
"OP_DEPTH" | "OP_DROP" | "OP_DUP" | "OP_NIP" | "OP_OVER" |
"OP_PICK" | "OP_ROLL" | "OP_ROT" | "OP_SWAP" | "OP_TUCK" |
"OP_2DROP" | "OP_2DUP" | "OP_3DUP" | "OP_2OVER" |
"OP_2ROT" | "OP_2SWAP" | "OP_SIZE" | "OP_EQUAL" |
"OP_EQUALVERIFY" | "OP_1ADD" | "OP_1SUB" | "OP_NEGATE" |
"OP_ABS" | "OP_NOT" | "OP_0NOTEQUAL" | "OP_ADD" |
"OP_SUB" | "OP_BOOLAND" | "OP_BOOLOR" | "OP_NUMEQUAL" |
"OP_NUMEQUALVERIFY" | "OP_NUMNOTEQUAL" | "OP_LESSTHAN" |
"OP_GREATERTHAN" | "OP_LESSTHANOREQUAL" |
"OP_GREATERTHANOREQUAL" | "OP_MIN" | "OP_MAX" |
"OP_WITHIN" | "OP_RIPEMD160" | "OP_SHA1" | "OP_SHA256" |
"OP_HASH160" | "OP_HASH256" | "OP_CODESEPARATOR" |
"OP_CHECKSIG" | "OP_CHECKSIGVERIFY" | "OP_CHECKMULTISIG" |
"OP_CHECKMULTISIGVERIFY" | "OP_CAT" | "OP_SPLIT" |
"OP_AND" | "OP_OR" | "OP_XOR" | "OP_DIV" | "OP_MOD" |
"OP_NUM2BIN" | "OP_BIN2NUM" | "OP_NOP1" | "OP_NOP2" |
"OP_NOP3" | "OP_NOP4" | "OP_NOP5" | "OP_NOP6" |
"OP_NOP7" | "OP_NOP8" | "OP_NOP9" | "OP_NOP10" |
"OP_MUL" | "OP_LSHIFT" | "OP_RSHIFT" | "OP_INVERT" |
"OP_2MUL" | "OP_2DIV" | "OP_VERIF" | "OP_VERNOTIF"
<non-script-data> ::= any sequence of bytes